s c h e m a t i c s : c o o k b o o k

This Web

Other Webs

Schematics

RSS

Scheme Links

The Post-Redirect-Get Pattern

Problem

When displaying a page after receiving a form submission, the browser's "refresh" button should not repost the form results.

Solution

The "Post-Redirect-Get" pattern, or PRG, is a popular web idiom for displaying a page after receiving a form ("POST") submission. The only action performed by the response to form submission is to redirect to an ordinary ("GET") page. This can be abstracted particularly nicely in PLT Scheme with the following simple procedure:

(define (redirect/get)
  (send/suspend
    (lambda (k-url)
      (redirect-to k-url))))

Now client code can simply apply this procedure after a form submission to redirect users to a "GET" page:

(define (start initial-request)
  (let ([request (send/suspend
                   (lambda (k-url)
                     ... form ...))])
    (redirect/get)
    (let ([user (extract-binding/single 'user (request-bindings request))])
      `(html (head (title "Hi"))
             (body (p "Hi, " ,user "! Hit refresh!"))))))

Discussion

Note that the redirect/get procedure returns the request object as a result of the "GET" interaction, though most of the time there won't be any interesting information in this request object that wasn't already in the result of the "POST".

My first implementation was as a special form, implemented as a simple macro whose subexpressions are evaluated in the context of the redirected GET page:

(define-syntax redirect/get
  (syntax-rules ()
    [(_ e ...)
     (send/suspend/dispatch
       (lambda (embed/url)
         (redirect-to (embed/url (lambda (_) e ...)))))]))

(This solution makes use of the send/suspend/dispatch procedure discussed in WebDispatchOnLink.)

However, I believe the solution using send/suspend is even easier to use and understand as a library procedure.

See also:

http://www.theserverside.com/articles/article.tss?l=RedirectAfterPost

Comments about this recipe

Contributors

-- DaveHerman - 30 Sep 2005

Changed to the simpler implementation with send/suspend.

-- DaveHerman - 02 Oct 2005